Программирование Викиданных/Естественные катастрофы

Исследуем свойства природных катастроф на основе базы знаний международного проекта Викиданные. С помощью SPARQL-запросов, вычисляемых на объектах типа "природные катастрофы" в Викиданных, далее решены такие задачи: выведен список всех стихийных бедствий мира, построена таблица с количеством природных катастроф по типам катастроф, построен список всех землетрясений, рассчитано количество землетрясений по странам. Кроме того, выполнена оценка полноты Викиданных по данной теме.

Экземпляры объекта "Естественные катастрофы"

Объект: стихийное бедствие (Q8065)

Построим список всех стихийных бедствий.

# List of subclasses of natural disaster
SELECT ?type ?typeLabel
WHERE
{
    ?type wdt:P279 wd:Q8065.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "ru, en, [AUTO_LANGUAGE]" }
}

SPARQL-запрос 19 стихийных бедствий на 2022 год.

👍 Наиболее полными и проработанными стихийными бедствиями на Викиданных являются: Наводнение в Европе, Рождественское наводнение, May 2004 Caribbean floods

👎 Почти пустыми и малоинформативными стихийными бедствиями оказались:Наводнения на Дальнем Востоке России и в Китае (2013), Землетрясение в Невельске (2007), Наводнение в Краснодарском крае (2012)

Типы природных катастроф

Построить таблицу с количеством природных катастроф по типам катастроф.

Объект: стихийное бедствие (Q8065)
Свойство: instance of (P31)

#count of natural disasters by type of disaster
SELECT ?d ?name (count(*) as ?count)
WHERE
{
    ?disaster wdt:P31 wd:Q8065. #is "instance of" natural disaster
    ?disaster wdt:P31 ?d. 
    OPTIONAL {?d rdfs:label ?name filter (lang(?name) = "en")}
}
GROUP BY ?d ?name
ORDER BY DESC(?count) ASC(?name)

SPARQL-запрос 35 результатов на 2022 год.

Получены следующие типы катастроф: наводнение, засуха, землетрясение, оползень, штормовая волна.

Полнота Викиданных

По данным учебного пособия "Основы безопасности жизнедеятельности и первой медицинской помощи" ^[1] естественные катастрофы можно разделить на:

метеорологические — бури, ураганы, смерчи, циклоны, морозы, засухи, необычайная жара, пожары;
теллурические и тектонические — извержения вулканов, землетрясение;
топологические — наводнения, сели, оползни, снежные обвалы.

В источниках можно найти разные классификации естественных катастроф, поэтому сложно выделить их точное количество.

С помощью SPARQL-скрипта получено девять записей, то есть девять типов естественных катастроф. Представлены наводнения, землетрясения, оползни, засухи, из книги Айзмана ^[1], нет бурь, ураганов, смерчей, циклонов, морозов, необычайной жары, пожаров, извержений вулканов, селей, и снежных обвалов из той же книги. В результате скрипта получилось, что больше всего новоднений (семь). Меньше всего - засух, землетрясений и оползней (по одному).

На Викиданных более полно представлены топологические катастрофы (наводнения и оползни) по классификации книги Айзмана ^[1], а меньше всего метеорологические (бури, ураганы, смерчи, циклоны, морозы, необычайная жара, пожары).

По данным категории "Стихийные бедствия" Русской Википедии существует 10 типов естественных катастроф. По данным категории "Natural disasters" Английской Википедии существует 15 типов естественных катастроф.

Землетрясения и вулканы

Построим список всех Землетрясений.

Объект: Землетрясение (Q7944)
Свойство: Это частный случай (P31)

#Names of earthquakes
SELECT DISTINCT ?earthquake ?earthquakeLabel
WHERE
{
  ?earthquake wdt:P31 wd:Q7944.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ru, en, [AUTO_LANGUAGE]" }
}

SPARQL-запрос 2363 землетрясений на 2022 год.

Построим список всех вулканов.

Объект: Вулкан (Q8072)

#Names of volcanoes
SELECT DISTINCT ?vulcano ?vulcanoLabel
WHERE
{
  ?vulcano wdt:P31 wd:Q8072.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ru, en, [AUTO_LANGUAGE]" }
}

SPARQL-запрос 1860 вулканов на 2022 год.

Посчитать количество землетрясений по странам.

Объект: Землетрясение (Q7944)
Свойство: country (P17)

# List of countries sorted by count of earthquakes
#defaultView:BarChart
SELECT ?countryLabel (count(?earthquake) as ?count) WHERE
{
    ?earthquake wdt:P31 wd:Q7944.
    ?earthquake wdt:P17 ?country. 
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}
GROUP BY ?country ?countryLabel

SPARQL-запрос 155 результатов на 2022 год.

Посчитать количество вулканов по странам.

Объект: Вулкан (Q8072)
Свойство: country (P17)

# List of countries sorted by count of volcanoes
SELECT ?countryLabel (count(?volcano) as ?count) WHERE
{
    ?volcano wdt:P17 ?country.
    ?volcano wdt:P31 wd:Q8072. # instance of volcano
    SERVICE wikibase:label { bd:serviceParam wikibase:language "ru, en" }
}
GROUP BY ?country ?countryLabel

SPARQL-запрос 83 результата на 2022 год.

Вывести координаты землетрясений .

Объект: Землетрясение (Q7944)
Свойство: coordinate location (P625)

# List of earthquake that have coordinates
#defaultView:Map
SELECT DISTINCT ?earthquake ?earthquakeLabel ?location WHERE
{
  ?earthquake  wdt:P31 wd:Q7944. # instance of volcano
  ?earthquake  wdt:P625 ?location; #coordinate location of earthquake
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ru, en, [AUTO_LANGUAGE]" }
}

SPARQL-запрос 1958 землетрясения на 2022 год.

Вывести координаты вулканов (Также показывает координаты вулканов на других космических телах).

Помимо того, что данный скрипт выводит названия всех вулканов на земле, также он выводит 27 вулканов на спутнике Юпитера Ио.

Объект: Вулкан (Q8072)
Свойство: coordinate location (P625)

# List of volcanoes that have coordinates
#defaultView:Map
SELECT DISTINCT ?volcano ?volcanoLabel ?location WHERE
{
  ?volcano wdt:P31 wd:Q8072. # instance of volcano
  ?volcano wdt:P625 ?location; #coordinate location of volcano
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ru, en, [AUTO_LANGUAGE]" }
}

SPARQL-запрос, 1716 вулканов на 2022 год.

Вывести координаты вулканов на планете Земля.

Объект: Вулкан (Q8072)
Свойство: coordinate location (P625)
Свойство: located on astronomical body (P376)

#Coordinates of volcanoes on Earth
SELECT DISTINCT ?volcano ?volcanoLabel ?location WHERE
{
  ?volcano wdt:P31 wd:Q8072. # instance of volcano
  ?volcano wdt:P625 ?location;
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ru, en" }
  FILTER ( NOT EXISTS { ?volcano  wdt:P376 [] } ) # Except vulcanoes on other space bodies
}

SPARQL-запрос, 1689 вулканов на 2022 год.

Диаграмма количества землетрясений по странам 2017 год.

Диаграмма количества землетрясений по странам 2022 год.

График количества землетрясений и вулканов по странам, 11 октября 2022 г.

Есть ли корреляция между числом вулканов и числом землетрясения? Да, такая связь между числом вулканов и числом землетрясения имеется и коэффициент корреляции этой связи равен 0,395. Зачастую эти катастрофические события происходят в одном месте с небольшим промежутком во времени. Например, в 1990 году на Филиппинах произошло землетрясение магнитудой 7,7, через некоторое время в 100 с лишним километрах от его эпицентра началось извержение вулкана Пинатубо^[2]. Происходит это потому, что сейсмические волны, вызванные землетрясениями, оказывают влияние на магму, находящуюся в жерле вулканов, вследствие чего происходит извержение^[3].

По этой ссылке можно посмотреть результат работы программы
Программа выводящая из данных CVS файлов карту в формате html с маркерами вулканом и землетрясений на 2022 год при помощи библиотеки folium^[4].

Вывести даты землетрясений.

Объект: Землетрясение (Q7944)
Свойство: point in time (P585)

# Dates of earthquakes
SELECT DISTINCT ?earthquake ?earthquakeLabel ?countryLabel ?date WHERE
{
  ?earthquake  wdt:P31 wd:Q7944. # instance of volcano
  ?earthquake wdt:P17 ?country.
  ?earthquake  wdt:P585 ?date; #Date of disaster 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ru, en, [AUTO_LANGUAGE]" }
}

SPARQL-запрос, 2150 дат на 2023 год.

Полнота Викиданных

С помощью первого SPARQL-скрипта получено 1547 записей. По данным учебного пособия "Общая геология для экологов" ^[5] за год в мире происходит около 100 сильных землетрясений в год, значит на Викиданных присутствуют записи о самых известных и крупных землетрясениях в мире. Сейсмографами регистрируется более 100 тыс. толчков в год.

С помощью второго SPARQL-скрипта получено, что на Викиданных представленны данные по 72 странам. По количеству землетрясений более всего заполнены страны: Америка, Япония, Китай. Реже всего встречаются страны: Румыния, Палестина, Словения.

Количество землетрясений в России по Викиданным равняется двум.

По данным РИА Новости ^[6] в 2013 году, только самых известных и крупных землетрясений в России произошло шесть, в 2012 - пять, в 2011 - три.

По данным категории Землетрясения в России Русской Википедии существует 27 землетрясений, произошедших в России. По данным категории Earthquakes in Russia Английской Википедии таких объектов 14.

После заполнения объектов количество землетрясений по Викиданным увеличилось, всего получено 1568 записей. В России стало 30 землетрясений. Также на Викиданных увеличилось число землетрясений в других странах: Румыния, Молдавия, Непал, КНР, Бутан, Бангладеш, Индия, Хорватия, Узбегистан, Индонезия, Сингапур, Малайзия, Таиланд, Словения, Италия, Пакистан, Афганистан, Иран, Киргизия, Украина, Болгария, Португалия, Алжир, Новая Зеландия, Бутан , Филиппины, Япония, Греция, Гватемала, Венесуэла. Увеличилось и число самих стран, в которых происходили землетрясения с 72 до 82.

Будущая работа

Посчитать количество наводнений по каждой стране и вывести результат в виде диаграммы.
Вычислить год, в который произошло наибольшее число наводнений.
Создать топ-10 природных катастроф, которые принесли людям наибольший экономический ущерб.

Упражнения

1	2	3	4
				Наводнение на Хуанхэ (1938)
				Великое наводнение на Миссисипи (1927)
				Наводнение в Китае (1931)
				Наводнение в странах Карибского бассейна (2004)

SPARQL-запросы с ответами:

значение магнитуды землетрясений по странам,
количество смертей при наводнениях, по убыванию
изображения наводнений

Примечания

Литература

Айзман Р.И. Основы безопасности жизнедеятельности и первой медицинской помощи. — Сибирское университетское издательство, 2002. — С. 396.
Константиновская Л. В. Общая геология для экологов (2 часть). — РУДН, 2010. — С. 102.
Крупные землетрясения в России в 2000-2013 годах (2017-03-21). Проверено 23 марта 2017.
Krizhanovsky A., Azarenkova E. Исследование землетрясений и других природных катастроф с помощью SPARQL-запросов. Authorea (2017). Проверено 18 апреля 2017.
Krizhanovsky A., Azarenkova E. Исследование землетрясений и других природных катастроф с помощью SPARQL-запросов. Научный Корреспондент (2017). Проверено 18 мая 2017.

[Айзман—2002——112-1] 1,0 ^1,1 ^1,2 Айзман, 2002, с. 112

[2] ttps://polit.ru/article/2016/04/30/ps_volcanology/

[3] ttps://scientificrussia.ru/articles/kak-zemletryasenie-vyzyvaet-izverzhenie-vulkanov

[4] ttps://github.com/componavt/wd_book/tree/master/programming_tasks/natural_disasters

[Константиновская—2010——-5] Константиновская, 2010

[Earthquakes_in_Russia_2000-2013—{{{2}}}——-6] Earthquakes in Russia 2000-2013

[1]

[2]

[3]

[4]

[5]

[6]

6.3	7.3	7.6
			Чуйское землетрясение (2003)
			Землетрясение на Байкале (2008)
			Землетрясение в Нефтегорске (1995)